garnet/flake.nix

{
  inputs = {
    nix-haskell.url = "github:reflex-frp/nix-haskell";
    nixpkgs.follows = "nix-haskell/nixpkgs";
    hls-src = { url = "github:haskell/haskell-language-server/2.13.0.0"; flake = false; };
    hs-bindgen-src = { url = "github:well-typed/hs-bindgen/release-0.1-alpha2"; flake = false; };
    libclang-src = { url = "github:well-typed/libclang"; flake = false; };
    flake-utils.url = "github:numtide/flake-utils";
    crane.url = "github:ipetkov/crane";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    inputs:
    inputs.flake-utils.lib.eachSystem [ "x86_64-linux" ] (system:
    let
      pkgs = haskell.nixpkgs.extend (import inputs.rust-overlay);
      nix-haskell = import inputs.nix-haskell { inherit system inputs; };
      crane = (inputs.crane.mkLib pkgs).overrideToolchain (p: p.rust-bin.selectLatestNightlyWith (
        toolchain: toolchain.default.override {
          extensions = [ "rust-src" ];
          targets = [ "x86_64-unknown-linux-gnu" ];
        }
      ));
      haskell =
        nix-haskell (import ./project.nix { inherit (inputs) hls-src hs-bindgen-src libclang-src; inherit garnet-rs; });
      garnet-rs = crane.buildPackage {
        src = crane.cleanCargoSource ./rust;
        doCheck = false;
        installPhaseCommand = ''
          mkdir -p $out/lib $out/include
          cp target/release/libgarnet_rs.a $out/lib/libCgarnet_rs.a
          cp target/release/garnet_rs.h $out/include/
        '';
      };
    in
    rec {
      defaultPackage = packages.garnet-exe;
      packages = let garnet = haskell.project.haskell-nix.hsPkgs.garnet; in {
        inherit garnet-rs;
        garnet-exe = garnet.components.exes.garnet;
        garnet-lib = garnet.components.library;
      };
      devShells.default = pkgs.mkShell {
        inputsFrom = [
          haskell.project.haskell-nix.shell
          (crane.devShell { })
        ];
        packages = with pkgs; [
          bacon
          ghcid
          rust-analyzer
        ];
      };
    });
}