{
  inputs = {
    nix-haskell.url = "github:reflex-frp/nix-haskell";
    hls-src = { url = "github:haskell/haskell-language-server/2.13.0.0"; flake = false; };
    hs-bindgen-src = { url = "github:well-typed/hs-bindgen/6ca94188abd756a1fb4dd8a4037de3fa7dca0765"; flake = false; };
    libclang-src = { url = "github:well-typed/libclang/d6e482df49b88375cf3075928a78ee86c2a068d4"; flake = false; };
    flake-utils.url = "github:numtide/flake-utils";
    crane.url = "github:ipetkov/crane";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nix-haskell/nixpkgs";
    };
  };
  outputs =
    inputs@{ nix-haskell, ... }:
    inputs.flake-utils.lib.eachSystem [ "x86_64-linux" ] (system:
    let
      lib = nix-haskell.lib.${system};
      project = lib.nix-haskell (import ./project.nix { inherit (inputs) hls-src hs-bindgen-src libclang-src; });
      haskell = project.haskell-nix.project;
      pkgs = project.nixpkgs.extend (import inputs.rust-overlay);
      rust = (inputs.crane.mkLib pkgs).overrideToolchain (p: p.rust-bin.selectLatestNightlyWith (
        toolchain: toolchain.default.override {
          extensions = [ "rust-src" ];
          targets = [ "x86_64-unknown-linux-gnu" ];
        }
      ));
    in
    {
      devShells.default = pkgs.mkShell {
        inputsFrom = [
          (haskell.shell.overrideAttrs (old: {
            shellHook = builtins.replaceStrings [ "*wasm*|)" ] [ "*wasm*)" ] old.shellHook;
          }))
          (rust.devShell { })
        ];
        packages = with pkgs; [
          bacon
          ghcid
          rust-analyzer
        ];
      };
    });
}