{

  inputs = {
    nix-haskell.url = "github:reflex-frp/nix-haskell";
    nixpkgs.follows = "nix-haskell/nixpkgs";
    flake-utils.url = "github:numtide/flake-utils";
    crane.url = "github:ipetkov/crane";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nix-haskell/nixpkgs";
    };
  };

  outputs = inputs@{ self, nixpkgs, ... }:
    inputs.flake-utils.lib.eachSystem [ "x86_64-linux" ] (system:
      let pkgs = (import nixpkgs { inherit system; }).extend (import inputs.rust-overlay);
          craneLib = (inputs.crane.mkLib pkgs).overrideToolchain (p: p.rust-bin.selectLatestNightlyWith (
            toolchain: toolchain.default.override {
              extensions = [ "rust-src" ];
              targets = [ "x86_64-unknown-linux-gnu" ];
            }
          ));
      in {
        packages.default = craneLib.buildPackage {
          src = craneLib.cleanCargoSource ./.;
          doCheck = false;
          installPhaseCommand = ''
            mkdir -p $out/lib $out/include
            cp target/release/libgarnet_rs.a $out/lib/libCgarnet_rs.a
            cp target/release/garnet_rs.h $out/include/
          '';
        };

        devShells.default = craneLib.devShell { };
      }
    );
}