garnet/flake.nix

{
  inputs = {
    haskell-nix.url = "github:input-output-hk/haskell.nix";
    hls-2-13 = { url = "github:haskell/haskell-language-server/2.13.0.0"; flake = false; };
    nixpkgs.follows = "haskell-nix/nixpkgs-2511";
    flake-utils.url = "github:numtide/flake-utils";
    crane.url = "github:ipetkov/crane";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    inputs@{ nixpkgs, ... }:
    inputs.flake-utils.lib.eachSystem [ "x86_64-linux" ] (system:
    let
      overlays = [
        inputs.haskell-nix.overlay
        (final: _prev: {
          hixProject =
            final.haskell-nix.hix.project {
              src = ./.;
              evalSystem = "x86_64-linux";
              name = "garnet";
              compiler-nix-name = "ghc9141";
              shell.tools.cabal = "latest";
              shell.withHoogle = false;
              shell.tools.haskell-language-server = {
                src = inputs.hls-2-13;
                sha256map = {
                  "https://github.com/snowleopard/alga"."d4e43fb42db05413459fb2df493361d5a666588a" = "0s1mlnl64wj7pkg3iipv5bb4syy3bhxwqzqv93zqlvkyfn64015i";
                };
              };
            };
        })
        (import inputs.rust-overlay)
      ];
      pkgs = import nixpkgs { inherit system overlays; inherit (inputs.haskell-nix) config; };
      haskell = pkgs.hixProject.flake { };
      rust = (inputs.crane.mkLib pkgs).overrideToolchain (p: p.rust-bin.selectLatestNightlyWith (
        toolchain: toolchain.default.override {
          extensions = [ "rust-src" ];
          targets = [ "x86_64-unknown-linux-gnu" ];
        }
      ));
    in
    {
      devShells.default = pkgs.mkShell {
        inputsFrom = [
          haskell.devShells.default
          (rust.devShell { })
        ];
        packages = with pkgs; [
          bacon
          ghcid
          llvmPackages.libclang
          rust-analyzer
          rust-cbindgen
        ];
      };
    });
}